Asp Resim Boyutlandırma

Doğru Cevap

11 yıl önce yazılmış

19 cevap - 19 soru

<%@ Language="VBScript.Encode" CODEPAGE="1254"%>
<% 
Function cevir(data) 
	data = Replace (data ,"ı","i",1,-1,1) 
	data = Replace (data ,"ğ","g",1,-1,1) 
	data = Replace (data ,"ü","u",1,-1,1) 
	data = Replace (data ,"ş","s",1,-1,1) 
	data = Replace (data ,"ö","o",1,-1,1) 
	data = Replace (data ,"ç","c",1,-1,1) 
	data = Replace (data ,"I","i",1,-1,1) 
	data = Replace (data ,"Ğ","g",1,-1,1) 
	data = Replace (data ,"Ü","u",1,-1,1) 
	data = Replace (data ,"Ş","s",1,-1,1) 
	data = Replace (data ,"İ","i",1,-1,1) 
	data = Replace (data ,"Ç","c",1,-1,1) 
	data = Replace (data ,"Ö","o",1,-1,1) 
	data = Replace (data ," ","-",1,-1,1)
	data = Replace (data ,">","",1,-1,1) 
	data = Replace (data ,"<","",1,-1,1) 
	data = Replace (data ,"*","",1,-1,1) 
	data = Replace (data ,"%","",1,-1,1) 
	data = Replace (data ,"'","",1,-1,1) 
	data = Replace (data ,"/","",1,-1,1)
	data = Replace (data ,"\","",1,-1,1)
	data = Replace (data ,"'","",1,-1,1)
	cevir=data 
End Function 
%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9" />
    <title>Yükle</title>
    <style>
    input {
        background:#fbfbfb;
        border:1px solid #cccccc;
        height:28px;
        padding:4px;
        font-size:12px;
        font-family:trebuchet ms;
    }
    </style>
</head>

<% 
on error resume next

'---------------------------- |DOSYA ADLANDIRMA 

cpr1=Year(date)				' tarih için Yılı öğrendik

Randomize
Numarax = INT (RND*9999999999)+3

cpr = numarax + 92

if month(date) < 10 then	' eğer ay 10 rakamından küçükse başına 0 ekledik
cpr2 = "0" & month(date)
else
cpr2 = month(date)			' değilse ayı olduğu gibi aldık 
end if

if Day(date) < 10 then		' eğer gün 10 rakamından küçükse başına 0 ekledik
cpr3 = "0" & Day(date)
else
cpr3 = Day(date)			' değilse günü olduğu gibi aldık
end if

' tarih oluşturma bölümü bitti

'---------------------------------------------------------------------------
	safha 	= Request.QueryString("safha")
	sayix 	= request("sayi")
	
	If safha = "" Then 
%>
    
<table border="0" cellpadding="5" cellspacing="5" width="100%" height="100%" style="border: 1px dotted #C0C0C0; background-color:#333333">
       <form action="upload.asp?safha=yukle&tip=resim&sayi=<%=sayix%>&id=<%=id%>" name="frm" id="frm" method="post" ENCtype="multipart/form-data">
        <tr>
            <td align="center"><input type="file" class="input" name="dosyaisim" size="35"></td>
        </tr>
        <tr>
            <td align="center"><input type="submit" value=" Dosyayı Yükle..." class="submit" onClick="this.value='Dosya yükleniyor..'"></td>
        </tr>
        </form>
    </table>
<% 
end If 
'---------------------------------------------------------------------
If safha="yukle" Then 	' Eğer dosya yükleme talimatı verilmiş ise
	
	dosyayeri = "upload/"	' Gönderdiğimiz dosyanın kaydedileceği dizini belirliyoruz
	dosya_adi = "dosya_" & cpr & cpr1 & cpr2 & cpr3

	' Dosya isminin ilerdede çakışmaması için veya dosya ismine biraz daha hava katmak için random sayı üretiyoruz
	Randomize
	Numara = INT (RND*9999999999)+1
	
	Server.ScriptTimeout=5000 ' --> Zaman Aşım Süresi  
	
	Set Upload = Server.CreateObject("Persits.Upload.1")  
	Upload.OverwriteFiles = False  
	Sayac = Upload.SaveToMemory  
	
	If Sayac = 0 Then 
	   Response.Write "Lütfen yüklemek üzere bir dosya seçiniz..."
	   Response.End 
	End If
	
	
	'----------- DOSYA KONTROLÜ
	For Each File in Upload.Files
	If FILE.EXT<>".jpg" then
	If FILE.EXT<>".jpeg" then
	Response.Write "Yüklemek istediğiniz dosya türüne müsaade verilmemiş / yasaklanmış..."   
	Response.End  
	end if
	end if
	next
	
	'--- KONTROL BİTİŞ

	Set dosya = Upload.Files ("dosyaisim") '--- Sorun Yoksa Dosyayı Yüklüyoruz.
	
	dosyaadi = dosya_adi&Numara&Right(dosya.FileName,4) ' Dosya Adı | Dokunmamakta Yarar Var.

	Path = Server.MapPath(dosyayeri & "/" & dosyaadi) ' Dosya Kaydetme Yeri | Dokunmamakta Yarar Var.
	
	dosya.SaveAs Path ' Dosya Kaydediliyor ...

'--------------------------------------------------------------------------------------------------------------------------
	' Küçültme 1
	Set Jpeg = Server.CreateObject("Persits.Jpeg" )
	Jpeg.Open Path
	Jpeg.Width = 240
	jpeg.Height = Jpeg.OriginalHeight * Jpeg.Width / Jpeg.OriginalWidth
	Jpeg.Canvas.Brush.Solid = False
	Path2 = Server.MapPath(dosyayeri & "/mini1/" & dosyaadi)
	Jpeg.Save Path2  
	YanlizYol	=	Server.MapPath(dosyayeri) 
	
	set Jpeg = nothing
'--------------------------------------------------------------------------------------------------------------------------
'Küçültme 2 --> Profesyonel Olanı
' Bunun mantığı yeni bir tuval oluşturur ve yüklenen resmi bu tuvale sığdırır...

	Set Jpeg = Server.CreateObject("Persits.Jpeg")
	Jpeg.New 800, 600, &HFFFFFF ' FFFFFF - > Beyaz Tuvale Çizer
	Jpeg.Canvas.Brush.Solid = TRUE ' Sağlam Fırça
	Jpeg.Quality 	= 100	' Resim Kalitesi | 1 ile 100 arasında bir sayı girilebilir . ne kadar düşerse kalitede o kadar düşer
	
	'-------- Çizim Başlıyor !
	Dim FileNames(1)
	
	FileNames(0) = dosyaadi
   
    Count = 0
	While Count < 1
		Set Img = Server.CreateObject("Persits.Jpeg")
		Img.Open YanlizYol & "/" & FileNames(Count)
		
		Img.PreserveAspectRatio = True
		If Img.OriginalWidth > 800 or Img.OriginalHeight > 600 Then
			If Img.OriginalWidth > Img.OriginalHeight Then
			   Img.Width = 800		
			Else
			   Img.Height = 600
			End If
		End If
		X = 0 + 120 * Count
		Y = 5
		
		Jpeg.Canvas.DrawImage X + (800 - Img.Width)/2, Y + (600 - Img.Height)/2, Img
		Count = Count + 1
	Wend

	
	Path3 = Server.MapPath(dosyayeri & "/" & dosyaadi)
	Jpeg.Save Path3
	
' -- BİTİŞ

%>
<br>
<div align="center">
<br>
<style>
body {
	font-size:12px;
	font-family:arial;
	color:#333333;
	padding:0px;
	margin:0px;
}
</style>
<h5>Dosya Yüklendi</h5><br />
<a href="#" onClick="window.opener.document.form.resim.value='<%=dosyaadi%>';self.close();">Kayıt İçin Lütfen Buraya Tıklayınız</a>
</div>
 <%end if%>
</body>
</html>

etkiweb
Bunu Bir Dene.Bu İşini Görür .

Çalıştırabilmek için

1- Persits Upload
2- Persits Jpeg

bileşenlerine ihtiyacın var. Çoğu Windows Hostingnde mevcuttur bunlar . Localde çalışıyorsan

www.aspjpeg.com 'dan Jpeg bileşenini
www.aspupload.com 'dan Upload bileşenini indirip kurabilirsin.
kolay gelsin.

11 yıl önce yazılmış

Cevaplar

11 yıl önce yazılmış

ontedi

39 cevap - 2 soru
Persist Aspjpeg ile yapabilirsin.
- ontedi
  Aslında sayfa yüklenirken jQuery ile de yapabilirsin. http://www.ontedi.com/javascript/jquery-ile-resimi-orantili-olarak-yeniden-boyutlandirmak.html
  
  11 yıl önce yazılmış
- murat1709
  Bana bir kod örneği sunabilirmisin
  
  11 yıl önce yazılmış
- Kesali
  http://www.kodaman.org/yazi/asp-ile-upload-ve-resize
  
  Bu linkte bir örnek var aslında kodlarıyla birlikte.
  Yalnız Persits ASP Upload ve Asp Jpeg her sunucuda olmuyor ücretli oldukları ve classic asp nin popülerliğinin azalması sebebiyle.
  
  11 yıl önce yazılmış

murat1709

Asp Resim Boyutlandırma

Doğru Cevap

Cevaplar